Contingut

# DIAFEINER.INTL

Returns the date calculated from a start date with a specific number of work days, before or after the start date. The calculation can include week-ends and holidays as non-working days.

### Sintaxi

WORKDAY.INTL(StartDate; Days [; Weekend [; Holidays]])

StartDate: is the date from when the calculation is carried out.

Dies és el nombre de dies feiners. El valor és positiu per a un resultat posterior a la data inicial, mentre que el valor és negatiu per a un resultat previ a la data inicial.

Weekend is an optional parameter – a number or a string used to specify the days of the week that are weekend days and are not considered working days. Weekend is a weekend number or string that specifies when weekends occur. Weekend number values indicate the following weekend days:

Number 1 to 7 for two-day weekends and 11 to 17 for one-day weekends.

Nombre | Cap de setmana
--- | ---
1 o omès | Dissabte i diumenge
2 | Diumenge i dilluns
3 | Dilluns i dimarts
4 | Dimarts i dimecres
5 | Dimecres i dijous
6 | Dijous i divendres
7 | Divendres i dissabte
11 | Només diumenge
12 | Només dilluns
13 | Només dimarts
14 | Només dimecres
15 | Només dijous
16 | Només divendres
17 | Només dissabte

Weekend string provides another way to define the weekly non-working days. It must have seven (7) characters – zeros (0) for working day and ones (1) for non-working day. Each character represents a day of the week, starting with Monday. Only 1 and 0 are valid. “1111111” is an invalid string and should not be used. For example, the weekend string “0000011” defines Saturday and Sunday as non-working days.

Holidays is an optional list of dates that must be counted as non-working days. The list can be given in a cell range.

En introduir dates com a part de fórmules, les barres i guionets usats com a separadors s'interpreten com a operadors aritmètics. Per tant, les dates en aquest format no es reconeixen com a dates i produeixen càlculs erronis. Per a evitar que les dates s'interpreti com a part de fórmules, feu servir la funció DATA — p. ex. DATA(1954;7;20)—, o escriviu la data entre cometes i en la notació ISO 8601 —p. ex. "1954-07-20"—. Eviteu fer servir formats de data regionals, com ara «07/20/54», perquè això pot generar error si el document s'obre amb una configuració regional diferent.

Unambiguous conversion is possible for ISO 8601 dates and times in their extended formats with separators. If a #VALUE! error occurs, then unselect Generate #VALUE! error in LibreOffice - Preferences Tools - Options - LibreOffice Calc - Formula, button Details... in section "Detailed Calculation Settings", Conversion from text to number list box.

### Exemples

What date comes 20 workdays after December 13, 2016? Enter the start date in C3 and the number of workdays in D3.

The weekend parameter (number) may be left blank or defined as 1 for default weekend (non-working days) – Saturday and Sunday.

Cells F3 to J3 contain five (5) holidays for Christmas and New Year in date format: December 24, 2016; December 25, 2016; December 26, 2016; December 31, 2016; and January 1, 2017.

=WORKDAY.INTL(C3;D3;;F3:J3) returns January 11, 2017 in the result cell, say D6 (use date format for the cell).

To define Friday and Saturday as weekend days, use the weekend parameter 7.

=WORKDAY.INTL(C3;D3;7;F3:J3) returns January 15, 2017 with weekend parameter 7.

To define Sunday only the weekend day, use the weekend parameter 11.

=WORKDAY.INTL(C3;D3;11;F3:J3) returns January 9, 2017.

Alternatively, use the weekend string "0000001" for Sunday only weekend.

=WORKDAY.INTL(C3;D3;"0000001";F3:J3) returns January 9, 2017.

The function can be used without the two optional parameters – Weekday and Holidays – by leaving them out:

=WORKDAY.INTL(C3;D3) gives the result: January 10, 2017.

#### Informació tècnica

Aquesta funció és disponible des de la versió 4.3 del LibreOffice.

This function is NOT part of the Open Document Format for Office Applications (OpenDocument) Version 1.3. Part 4: Recalculated Formula (OpenFormula) Format standard. The name space is

COM.MICROSOFT.WORKDAY.INTL

Temes relacionats

WORKDAY.INTL wiki page.

Funcions de data i hora

DATA

DIFDATES

VALORDATA

DIA

DIES

DIES360

DAYSINMONTH

DAYSINYEAR

DIUMENGEPASQUA

DATAE

FDMES

HORA

ISLEAPYEAR

NUMSETMANA.ISO

MINUT

MES

MONTHS

DIESFEINERSNETS

DIESFEINERSNETS.INTL

ARA

SEGON

HORADEC

VALORHORA

AVUI

DIASETMANA

NUMSETMANA

NUMSETMANA_EXCEL2003

NUMSETMANA_OOO

WEEKS

WEEKSINYEAR

DIAFEINER

DIAFEINER.INTL

ANY

FRACANY

YEARS